# Script pour la conférence des mercredis de la Physique, 15/12/2004
# Requis: texture haute résolution de la terre 
#     (attention, 1G d'espace disque! http://celestia.h-schmidt.net/earth-vt/
# Jean Orloff <orloff@in2p3.fr>

{


	select { object "Sol/Earth" }
	synchronous {}
	setsurface { name "Earth 32k Normalmap+Nightlights+Spec" }
	goto { time 5 }
	time { utc "2005-10-12T13:00:00" }
	timerate { rate 1 }
	# gotolonglat { time 0 distance 1e11 longitude 0 latitude 0 }
        gotolonglat { time 0 distance 1.025 longitude 2.96 latitude 45.780 } # Puy-de-Dome
	wait { duration 1.0 }
	labels { clear "planets|minorplanets|stars|constellations|moons|galaxies|spacecraft|asteroid" }
	renderflags { set "stars|planets|atmospheres|galaxies|nightmaps"
                      clear "constellations|orbits|cloudmaps" }
        gotolonglat { time 0 distance 1.025 longitude 2.96 latitude 45.780 } # Puy-de-Dome
	synchronous { }
	center {}
	set { name "FOV" value 70.0 }
	wait { duration 1 }



	print { text "Nous voici a la verticale du Puy de Dome;
Reconnaissez-vous le Sancy, le Forez, le Cantal? 
Clermont-Ferrand? " row -5 duration 9 }
	wait { duration 4 }
	labels { set "location" }
	wait { duration 6 }


	print { text "Faisons s'ecouler 2 jours en 20s:
		les ombres jouent autour du Sancy et du Cantal..." row -4 duration 5 }
	wait { duration 6 }
	timerate { rate 8640 }
	wait { duration 2 }	
	print { text "... et les lumieres des villes s'allument: Clermont, Lyon, Limoges" row -3 duration 5 }
	wait { duration 18 }
	time { utc "2005-10-12T13:00:00" }
	timerate { rate 1 }

	print { text "Prenons maintenant un peu de champ: passons de 160km a 320km d'altitude..." row -3 duration 5 }
        gotolonglat { time 10 distance 1.05 longitude 2.96 latitude 45.780 }
	wait { duration 10 }

	print { text "puis a 640km d'altitude..." row -3 duration 5 }
        gotolonglat { time 10 distance 1.1 longitude 2.96 latitude 45.780 }
	wait {duration 10 }

	print { text "... a 1200km d'altitude..." row -3 duration 4 }
        gotolonglat { time 6 distance 1.2 longitude 2.96 latitude 45.780 }
	wait {duration 6 }

	timerate { rate 1440 }
	print { text "... et a 6400km d'altitude" row -3 duration 9 }
        gotolonglat { time 15 distance 2 longitude 2.96 latitude 45.780 }
	wait { duration 11 }

	print { text "Nous sommes toujours geostationnaires a la verticale du
Puy de Dome; 24h s'ecoulent maintenant en 1 min." row -4 duration 5 }
	wait { duration 6 }

	print { text "Reperons-nous avec les planetes et les constellations," row -3 duration 5 }
	wait { duration 5 }
	labels { set "galaxies|moons|constellations" }
	renderflags { set "constellations" }

	print { text "Le soleil est couche sur Clermont; le ciel que nous
		voyons derriere ne nous est donc pas familier" row -4 duration 9 }
	wait { duration 10}
	labels { set "planets" }

	select {object "Sol/Earth" }
	print { 
		text "Eloignons-nous de la terre: premier arret: la lune"
		row -3
		duration 5
	}
	goto { distance 100 time 7 }
	wait {duration 3}
	renderflags { set "orbits" }	
	print { 
		text "Visualisons les orbites,"
		row -3
		duration 5
	}
	wait { duration 5}	

	goto { distance 40000 time 7 }
	print { 
		text "avec les planetes internes..."
		row -3
		duration 5
	}
	wait { duration 5 }

	goto { distance 1500000 time 7 }
	print { 
		text "... et le systeme solaire entier"
		row -3
		duration 5
	}
	wait { duration 10 }

	print {
		text "Tournons-nous le Taureau:
on y trouve la nebuleuse M1 dite du Crabe" 
		row -4
		duration 7
	}

# deselect track if any...
	select { object "" }
	track  { }
	select { object "SN 1054" }
	timerate { rate 1 }
	center { time 7 }
	wait { duration 7 }

	print{ text "et les debris d'explosion de 
la supernova SN 1054, vue en 1054
par les chinois et les Indiens d'Amerique"
		row -5
		duration 7
	}
	goto { time 10 distance 3.0 }
	wait { duration 10 }
	print{ text "Nous sommes a 6300 annees-lumieres de la terre:
l'explosion a eu lieu il y a 7000 ans,
les debris ont vole pendant 1000 ans" row -5 duration 7 }
	wait { duration 7 }

	labels { clear "stars|constellations" }
	print { text "Retournons-nous vers la terre,
		au centre des constellations vues de l'exterieur" row -4 duration 5 }
#	orbit { rate 30 duration 6 }
	select { object "Sol/Earth" }
	center { time 5 }
	wait { duration 6 }
	track {}

	print { text "Pour nous situer dans la galaxie,
		eloignons-nous a 100000 annees-lumieres" row -4 duration 6 }
        goto { distance 150000000000000 time 7 }
	wait { duration 7 }
	print { text "et remettons-nous en orbite geostationnaire" row -3 duration 4 }

	timerate { rate 14400 }
#	select { object "Sol/Earth" }
	synchronous {}
	track {}
	wait { duration 5 }

	print { text "Retour sur terre: attention ca tourne!" 
		row -3 duration 10 }
	wait { duration 3 }

# 	timerate { rate 2880 }
#        gotolonglat { time 9 distance 10000000 longitude 2.96 latitude 45.780 }
        gotolonglat { time 20 distance 2 longitude 2.96 latitude 45.780 }
	wait { duration 20 }
	timerate { rate 1440 }
	labels { clear "planets|minorplanets|stars|constellations|moons|galaxies|asteroid" }
	renderflags { set "stars|planets|atmospheres|galaxies"
                      clear "constellations|orbits|cloudmaps" }
	labels { set "spacecraft|moons" }
	print { text "Bien que voyageant a la vitesse de la lumiere,
		un rayon cosmique de la Supernova du Crabe tournera
		bien plus que nous, et mettra en moyenne
		des centaines de millions d'annees pour nous atteindre..."
		 row -6 duration 10 }
	wait { duration 11 }
	print { text "Realisation: J. Orloff, avec CELESTIA" row -3 duration 10 }
	wait { duration 10 }
	
}